Flatkit 추가 및 설정

Assets/FlatKit/Demos/[Demo] Desert/Shaders/Noise/ClassicNoise2D.hlsl

@@ -0,0 +1,66 @@
+//
+// GLSL textureless classic 2D noise "cnoise",
+// with an RSL-style periodic variant "pnoise".
+// Author:  Stefan Gustavson (stefan.gustavson@liu.se)
+// Version: 2011-08-22
+//
+// Many thanks to Ian McEwan of Ashima Arts for the
+// ideas for permutation and gradient selection.
+//
+// Copyright (c) 2011 Stefan Gustavson. All rights reserved.
+// Distributed under the MIT license. See LICENSE file.
+// https://github.com/ashima/webgl-noise
+//
+
+#ifndef _INCLUDE_JP_KEIJIRO_NOISESHADER_CLASSIC_NOISE_2D_HLSL_
+#define _INCLUDE_JP_KEIJIRO_NOISESHADER_CLASSIC_NOISE_2D_HLSL_
+
+#include "Common.hlsl"
+
+float ClassicNoise_impl(float2 pi0, float2 pf0, float2 pi1, float2 pf1)
+{
+    pi0 = wglnoise_mod289(pi0); // To avoid truncation effects in permutation
+    pi1 = wglnoise_mod289(pi1);
+
+    float4 ix = float2(pi0.x, pi1.x).xyxy;
+    float4 iy = float2(pi0.y, pi1.y).xxyy;
+    float4 fx = float2(pf0.x, pf1.x).xyxy;
+    float4 fy = float2(pf0.y, pf1.y).xxyy;
+
+    float4 i = wglnoise_permute(wglnoise_permute(ix) + iy);
+
+    float4 phi = i / 41 * 3.14159265359 * 2;
+    float2 g00 = float2(cos(phi.x), sin(phi.x));
+    float2 g10 = float2(cos(phi.y), sin(phi.y));
+    float2 g01 = float2(cos(phi.z), sin(phi.z));
+    float2 g11 = float2(cos(phi.w), sin(phi.w));
+
+    float n00 = dot(g00, float2(fx.x, fy.x));
+    float n10 = dot(g10, float2(fx.y, fy.y));
+    float n01 = dot(g01, float2(fx.z, fy.z));
+    float n11 = dot(g11, float2(fx.w, fy.w));
+
+    float2 fade_xy = wglnoise_fade(pf0);
+    float2 n_x = lerp(float2(n00, n01), float2(n10, n11), fade_xy.x);
+    float n_xy = lerp(n_x.x, n_x.y, fade_xy.y);
+    return 1.44 * n_xy;
+}
+
+// Classic Perlin noise
+float ClassicNoise(float2 p)
+{
+    float2 i = floor(p);
+    float2 f = frac(p);
+    return ClassicNoise_impl(i, f, i + 1, f - 1);
+}
+
+// Classic Perlin noise, periodic variant
+float PeriodicNoise(float2 p, float2 rep)
+{
+    float2 i0 = wglnoise_mod(floor(p), rep);
+    float2 i1 = wglnoise_mod(i0 + 1, rep);
+    float2 f = frac(p);
+    return ClassicNoise_impl(i0, f, i1, f - 1);
+}
+
+#endif

Assets/FlatKit/Demos/[Demo] Desert/Shaders/Noise/ClassicNoise2D.hlsl.meta

@@ -0,0 +1,9 @@
+fileFormatVersion: 2
+guid: dcbc3be8e5ec84a48a61ce519e461532
+timeCreated: 1498976326
+licenseType: Pro
+ShaderImporter:
+  defaultTextures: []
+  userData: 
+  assetBundleName: 
+  assetBundleVariant: 

Assets/FlatKit/Demos/[Demo] Desert/Shaders/Noise/ClassicNoise3D.hlsl

@@ -0,0 +1,93 @@
+//
+// GLSL textureless classic 3D noise "cnoise",
+// with an RSL-style periodic variant "pnoise".
+// Author:  Stefan Gustavson (stefan.gustavson@liu.se)
+// Version: 2011-10-11
+//
+// Many thanks to Ian McEwan of Ashima Arts for the
+// ideas for permutation and gradient selection.
+//
+// Copyright (c) 2011 Stefan Gustavson. All rights reserved.
+// Distributed under the MIT license. See LICENSE file.
+// https://github.com/ashima/webgl-noise
+//
+
+#ifndef _INCLUDE_JP_KEIJIRO_NOISESHADER_CLASSIC_NOISE_3D_HLSL_
+#define _INCLUDE_JP_KEIJIRO_NOISESHADER_CLASSIC_NOISE_3D_HLSL_
+
+#include "Common.hlsl"
+
+float ClassicNoise_impl(float3 pi0, float3 pf0, float3 pi1, float3 pf1)
+{
+    pi0 = wglnoise_mod289(pi0);
+    pi1 = wglnoise_mod289(pi1);
+
+    float4 ix = float4(pi0.x, pi1.x, pi0.x, pi1.x);
+    float4 iy = float4(pi0.y, pi0.y, pi1.y, pi1.y);
+    float4 iz0 = pi0.z;
+    float4 iz1 = pi1.z;
+
+    float4 ixy = wglnoise_permute(wglnoise_permute(ix) + iy);
+    float4 ixy0 = wglnoise_permute(ixy + iz0);
+    float4 ixy1 = wglnoise_permute(ixy + iz1);
+
+    float4 gx0 = lerp(-1, 1, frac(floor(ixy0 / 7) / 7));
+    float4 gy0 = lerp(-1, 1, frac(floor(ixy0 % 7) / 7));
+    float4 gz0 = 1 - abs(gx0) - abs(gy0);
+
+    bool4 zn0 = gz0 < -0.01;
+    gx0 += zn0 * (gx0 < -0.01 ? 1 : -1);
+    gy0 += zn0 * (gy0 < -0.01 ? 1 : -1);
+
+    float4 gx1 = lerp(-1, 1, frac(floor(ixy1 / 7) / 7));
+    float4 gy1 = lerp(-1, 1, frac(floor(ixy1 % 7) / 7));
+    float4 gz1 = 1 - abs(gx1) - abs(gy1);
+
+    bool4 zn1 = gz1 < -0.01;
+    gx1 += zn1 * (gx1 < -0.01 ? 1 : -1);
+    gy1 += zn1 * (gy1 < -0.01 ? 1 : -1);
+
+    float3 g000 = normalize(float3(gx0.x, gy0.x, gz0.x));
+    float3 g100 = normalize(float3(gx0.y, gy0.y, gz0.y));
+    float3 g010 = normalize(float3(gx0.z, gy0.z, gz0.z));
+    float3 g110 = normalize(float3(gx0.w, gy0.w, gz0.w));
+    float3 g001 = normalize(float3(gx1.x, gy1.x, gz1.x));
+    float3 g101 = normalize(float3(gx1.y, gy1.y, gz1.y));
+    float3 g011 = normalize(float3(gx1.z, gy1.z, gz1.z));
+    float3 g111 = normalize(float3(gx1.w, gy1.w, gz1.w));
+
+    float n000 = dot(g000, pf0);
+    float n100 = dot(g100, float3(pf1.x, pf0.y, pf0.z));
+    float n010 = dot(g010, float3(pf0.x, pf1.y, pf0.z));
+    float n110 = dot(g110, float3(pf1.x, pf1.y, pf0.z));
+    float n001 = dot(g001, float3(pf0.x, pf0.y, pf1.z));
+    float n101 = dot(g101, float3(pf1.x, pf0.y, pf1.z));
+    float n011 = dot(g011, float3(pf0.x, pf1.y, pf1.z));
+    float n111 = dot(g111, pf1);
+
+    float3 fade_xyz = wglnoise_fade(pf0);
+    float4 n_z = lerp(float4(n000, n100, n010, n110),
+                      float4(n001, n101, n011, n111), fade_xyz.z);
+    float2 n_yz = lerp(n_z.xy, n_z.zw, fade_xyz.y);
+    float n_xyz = lerp(n_yz.x, n_yz.y, fade_xyz.x);
+    return 1.46 * n_xyz;
+}
+
+// Classic Perlin noise
+float ClassicNoise(float3 p)
+{
+    float3 i = floor(p);
+    float3 f = frac(p);
+    return ClassicNoise_impl(i, f, i + 1, f - 1);
+}
+
+// Classic Perlin noise, periodic variant
+float PeriodicNoise(float3 p, float3 rep)
+{
+    float3 i0 = wglnoise_mod(floor(p), rep);
+    float3 i1 = wglnoise_mod(i0 + 1, rep);
+    float3 f = frac(p);
+    return ClassicNoise_impl(i0, f, i1, f - 1);
+}
+
+#endif

Assets/FlatKit/Demos/[Demo] Desert/Shaders/Noise/ClassicNoise3D.hlsl.meta

@@ -0,0 +1,9 @@
+fileFormatVersion: 2
+guid: 739cd3762c77bdc4fa27ff1c6af5c017
+timeCreated: 1498976326
+licenseType: Pro
+ShaderImporter:
+  defaultTextures: []
+  userData: 
+  assetBundleName: 
+  assetBundleVariant: 

Assets/FlatKit/Demos/[Demo] Desert/Shaders/Noise/Common.hlsl

@@ -0,0 +1,64 @@
+#ifndef _INCLUDE_JP_KEIJIRO_NOISESHADER_COMMON_HLSL_
+#define _INCLUDE_JP_KEIJIRO_NOISESHADER_COMMON_HLSL_
+
+float wglnoise_mod(float x, float y)
+{
+    return x - y * floor(x / y);
+}
+
+float2 wglnoise_mod(float2 x, float2 y)
+{
+    return x - y * floor(x / y);
+}
+
+float3 wglnoise_mod(float3 x, float3 y)
+{
+    return x - y * floor(x / y);
+}
+
+float4 wglnoise_mod(float4 x, float4 y)
+{
+    return x - y * floor(x / y);
+}
+
+float2 wglnoise_fade(float2 t)
+{
+    return t * t * t * (t * (t * 6 - 15) + 10);
+}
+
+float3 wglnoise_fade(float3 t)
+{
+    return t * t * t * (t * (t * 6 - 15) + 10);
+}
+
+float wglnoise_mod289(float x)
+{
+    return x - floor(x / 289) * 289;
+}
+
+float2 wglnoise_mod289(float2 x)
+{
+    return x - floor(x / 289) * 289;
+}
+
+float3 wglnoise_mod289(float3 x)
+{
+    return x - floor(x / 289) * 289;
+}
+
+float4 wglnoise_mod289(float4 x)
+{
+    return x - floor(x / 289) * 289;
+}
+
+float3 wglnoise_permute(float3 x)
+{
+    return wglnoise_mod289((x * 34 + 1) * x);
+}
+
+float4 wglnoise_permute(float4 x)
+{
+    return wglnoise_mod289((x * 34 + 1) * x);
+}
+
+#endif

Assets/FlatKit/Demos/[Demo] Desert/Shaders/Noise/Common.hlsl.meta

@@ -0,0 +1,10 @@
+fileFormatVersion: 2
+guid: 443fb5ca2e0ec42bc8a96eb43c8470fe
+ShaderImporter:
+  externalObjects: {}
+  defaultTextures: []
+  nonModifiableTextures: []
+  preprocessorOverride: 0
+  userData: 
+  assetBundleName: 
+  assetBundleVariant: 

Assets/FlatKit/Demos/[Demo] Desert/Shaders/Noise/LICENSE

@@ -0,0 +1,20 @@
+Copyright (C) 2011 by Ashima Arts (Simplex noise)
+Copyright (C) 2011-2016 by Stefan Gustavson (Classic noise and others)
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in
+all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
+THE SOFTWARE.

Assets/FlatKit/Demos/[Demo] Desert/Shaders/Noise/LICENSE.meta

@@ -0,0 +1,7 @@
+fileFormatVersion: 2
+guid: 41d8ee8abf4f9054d92973873b8fdcf8
+DefaultImporter:
+  externalObjects: {}
+  userData: 
+  assetBundleName: 
+  assetBundleVariant: